You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
549 lines
19 KiB
549 lines
19 KiB
# See docs/CMake.html for instructions about how to build LLVM with CMake.
|
|
|
|
cmake_minimum_required(VERSION 2.8.7)
|
|
|
|
set(LLVM_INSTALL_TOOLCHAIN_ONLY ON)
|
|
|
|
if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
|
|
message(STATUS "No build type selected, default to Debug")
|
|
set(CMAKE_BUILD_TYPE "Debug")
|
|
endif()
|
|
|
|
if(POLICY CMP0022)
|
|
cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
|
|
endif()
|
|
|
|
if (POLICY CMP0051)
|
|
# CMake 3.1 and higher include generator expressions of the form
|
|
# $<TARGETLIB:obj> in the SOURCES property. These need to be
|
|
# stripped everywhere that access the SOURCES property, so we just
|
|
# defer to the OLD behavior of not including generator expressions
|
|
# in the output for now.
|
|
cmake_policy(SET CMP0051 OLD)
|
|
endif()
|
|
|
|
if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
|
|
set(cmake_3_2_USES_TERMINAL)
|
|
else()
|
|
set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
|
|
endif()
|
|
|
|
if(NOT DEFINED LLVM_VERSION_MAJOR)
|
|
set(LLVM_VERSION_MAJOR 3)
|
|
endif()
|
|
if(NOT DEFINED LLVM_VERSION_MINOR)
|
|
set(LLVM_VERSION_MINOR 9)
|
|
endif()
|
|
if(NOT DEFINED LLVM_VERSION_PATCH)
|
|
set(LLVM_VERSION_PATCH 0)
|
|
endif()
|
|
if(NOT DEFINED LLVM_VERSION_SUFFIX)
|
|
set(LLVM_VERSION_SUFFIX svn)
|
|
endif()
|
|
|
|
if (POLICY CMP0048)
|
|
cmake_policy(SET CMP0048 NEW)
|
|
set(cmake_3_0_PROJ_VERSION
|
|
VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH})
|
|
set(cmake_3_0_LANGUAGES LANGUAGES)
|
|
endif()
|
|
|
|
if (NOT PACKAGE_VERSION)
|
|
set(PACKAGE_VERSION
|
|
"${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
|
|
endif()
|
|
|
|
project(LLVM
|
|
${cmake_3_0_PROJ_VERSION}
|
|
${cmake_3_0_LANGUAGES}
|
|
C CXX ASM)
|
|
|
|
# The following only works with the Ninja generator in CMake >= 3.0.
|
|
set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
|
|
"Define the maximum number of concurrent compilation jobs.")
|
|
if(LLVM_PARALLEL_COMPILE_JOBS)
|
|
if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
|
|
message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
|
|
else()
|
|
set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
|
|
set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
|
|
endif()
|
|
endif()
|
|
|
|
set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
|
|
"Define the maximum number of concurrent link jobs.")
|
|
if(LLVM_PARALLEL_LINK_JOBS)
|
|
if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
|
|
message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
|
|
else()
|
|
set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
|
|
set(CMAKE_JOB_POOL_LINK link_job_pool)
|
|
endif()
|
|
endif()
|
|
|
|
# Add path for custom modules
|
|
set(CMAKE_MODULE_PATH
|
|
${CMAKE_MODULE_PATH}
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/cmake"
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
|
|
)
|
|
|
|
# Generate a CompilationDatabase (compile_commands.json file) for our build,
|
|
# for use by clang_complete, YouCompleteMe, etc.
|
|
set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
|
|
|
|
option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
|
|
if ( LLVM_USE_FOLDERS )
|
|
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
|
|
endif()
|
|
|
|
include(VersionFromVCS)
|
|
|
|
option(LLVM_APPEND_VC_REV
|
|
"Append the version control system revision id to LLVM version" OFF)
|
|
|
|
if( LLVM_APPEND_VC_REV )
|
|
add_version_info_from_vcs(PACKAGE_VERSION)
|
|
endif()
|
|
|
|
set(PACKAGE_NAME LLVM)
|
|
set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
|
|
set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
|
|
|
|
set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
|
|
"Default URL where bug reports are to be submitted.")
|
|
|
|
# Configure CPack.
|
|
set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
|
|
set(CPACK_PACKAGE_VENDOR "LLVM")
|
|
set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
|
|
set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
|
|
set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
|
|
set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
|
|
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
|
|
set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
|
|
if(WIN32 AND NOT UNIX)
|
|
set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
|
|
set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
|
|
set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
|
|
set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
|
|
set(CPACK_NSIS_MODIFY_PATH "ON")
|
|
set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
|
|
set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
|
|
"ExecWait '$INSTDIR/tools/msbuild/install.bat'")
|
|
set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
|
|
"ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
|
|
if( CMAKE_CL_64 )
|
|
set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
|
|
endif()
|
|
endif()
|
|
include(CPack)
|
|
|
|
string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
|
|
|
|
if (CMAKE_BUILD_TYPE AND
|
|
NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL|NONE)$")
|
|
message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
|
|
endif()
|
|
|
|
set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
|
|
|
|
# They are used as destination of target generators.
|
|
set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
|
|
set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
|
|
if(WIN32 OR CYGWIN)
|
|
# DLL platform -- put DLLs into bin.
|
|
set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
|
|
else()
|
|
set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
|
|
endif()
|
|
|
|
# Each of them corresponds to llvm-config's.
|
|
set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
|
|
set(LLVM_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
|
|
set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR} ) # --src-root
|
|
set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
|
|
set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR} ) # --prefix
|
|
|
|
set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
|
|
set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
|
|
|
|
set(LLVM_ALL_TARGETS
|
|
AArch64
|
|
# AMDGPU
|
|
ARM
|
|
Hexagon
|
|
Mips
|
|
PowerPC
|
|
Sparc
|
|
SystemZ
|
|
X86
|
|
)
|
|
|
|
set(LLVM_TARGETS_TO_BUILD "all"
|
|
CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
|
|
|
|
set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
|
|
CACHE STRING "Semicolon-separated list of experimental targets to build.")
|
|
|
|
option(BUILD_SHARED_LIBS
|
|
"Build all libraries as shared libraries instead of static" OFF)
|
|
|
|
option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
|
|
if(LLVM_ENABLE_TIMESTAMPS)
|
|
set(ENABLE_TIMESTAMPS 1)
|
|
endif()
|
|
|
|
option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
|
|
if(LLVM_ENABLE_BACKTRACES)
|
|
set(ENABLE_BACKTRACES 1)
|
|
endif()
|
|
|
|
option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
|
|
if(LLVM_ENABLE_CRASH_OVERRIDES)
|
|
set(ENABLE_CRASH_OVERRIDES 1)
|
|
endif()
|
|
|
|
option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
|
|
set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
|
|
set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
|
|
|
|
set(LLVM_TARGET_ARCH "host"
|
|
CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
|
|
|
|
option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
|
|
|
|
option(LLVM_ENABLE_THREADS "Use threads if available." ON)
|
|
|
|
option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
|
|
|
|
if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
|
|
set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
|
|
endif()
|
|
|
|
set(LLVM_TARGETS_TO_BUILD
|
|
${LLVM_TARGETS_TO_BUILD}
|
|
${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
|
|
list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
|
|
|
|
include(AddLLVMDefinitions)
|
|
|
|
option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
|
|
option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
|
|
option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
|
|
option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
|
|
option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
|
|
option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
|
|
option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
|
|
option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
|
|
|
|
if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
|
|
option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
|
|
else()
|
|
option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
|
|
endif()
|
|
|
|
set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
|
|
"Enable abi-breaking checks. Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
|
|
|
|
option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
|
|
"Set to ON to force using an old, unsupported host toolchain." OFF)
|
|
|
|
option(LLVM_EXTERNALIZE_DEBUGINFO
|
|
"Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
|
|
|
|
# If enabled, verify we are on a platform that supports oprofile.
|
|
if( LLVM_USE_OPROFILE )
|
|
if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
|
|
message(FATAL_ERROR "OProfile support is available on Linux only.")
|
|
endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
|
|
endif( LLVM_USE_OPROFILE )
|
|
|
|
set(LLVM_USE_SANITIZER "" CACHE STRING
|
|
"Define the sanitizer used to build binaries and tests.")
|
|
|
|
option(LLVM_USE_SPLIT_DWARF
|
|
"Use -gsplit-dwarf when compiling llvm." OFF)
|
|
|
|
# Define an option controlling whether we should build for 32-bit on 64-bit
|
|
# platforms, where supported.
|
|
if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
|
|
# TODO: support other platforms and toolchains.
|
|
option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
|
|
endif()
|
|
|
|
# Define the default arguments to use with 'lit', and an option for the user to
|
|
# override.
|
|
set(LIT_ARGS_DEFAULT "-sv")
|
|
if (MSVC_IDE OR XCODE)
|
|
set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
|
|
endif()
|
|
set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
|
|
|
|
# On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
|
|
if( WIN32 AND NOT CYGWIN )
|
|
set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
|
|
endif()
|
|
|
|
option(LLVM_BUILD_RUNTIME
|
|
"Build the LLVM runtime libraries." ON)
|
|
|
|
option(LLVM_BUILD_TESTS
|
|
"Build LLVM unit tests. If OFF, just generate build targets." OFF)
|
|
|
|
# You can configure which libraries from LLVM you want to include in the
|
|
# shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
|
|
# list of LLVM components. All component names handled by llvm-config are valid.
|
|
if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
|
|
set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
|
|
"Semicolon-separated list of components to include in libLLVM, or \"all\".")
|
|
endif()
|
|
option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
|
|
option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
|
|
set(LLVM_BUILD_LLVM_DYLIB_default OFF)
|
|
if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
|
|
set(LLVM_BUILD_LLVM_DYLIB_default ON)
|
|
endif()
|
|
option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
|
|
set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT ON)
|
|
if (LLVM_LINK_LLVM_DYLIB)
|
|
set(LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT OFF)
|
|
endif()
|
|
option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ${LLVM_DISABLE_LLVM_DYLIB_ATEXIT_DEFAULT})
|
|
if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
|
|
set(DISABLE_LLVM_DYLIB_ATEXIT 1)
|
|
endif()
|
|
|
|
if(CMAKE_CROSSCOMPILING)
|
|
set(LLVM_USE_HOST_TOOLS ON)
|
|
endif()
|
|
|
|
# All options referred to from HandleLLVMOptions have to be specified
|
|
# BEFORE this include, otherwise options will not be correctly set on
|
|
# first cmake run
|
|
include(config-ix)
|
|
|
|
# By default, we target the host, but this can be overridden at CMake
|
|
# invocation time.
|
|
set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
|
|
"Default target for which LLVM will generate code." )
|
|
set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
|
|
|
|
include(HandleLLVMOptions)
|
|
|
|
# Verify that we can find a Python 2 interpreter. Python 3 is unsupported.
|
|
# FIXME: We should support systems with only Python 3, but that requires work
|
|
# on LLDB.
|
|
set(Python_ADDITIONAL_VERSIONS 2.7)
|
|
include(FindPythonInterp)
|
|
if( NOT PYTHONINTERP_FOUND )
|
|
message(FATAL_ERROR
|
|
"Unable to find Python interpreter, required for builds and testing.
|
|
|
|
Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
|
|
endif()
|
|
|
|
if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
|
|
message(FATAL_ERROR "Python 2.7 or newer is required")
|
|
endif()
|
|
|
|
######
|
|
# LLVMBuild Integration
|
|
#
|
|
# We use llvm-build to generate all the data required by the CMake based
|
|
# build system in one swoop:
|
|
#
|
|
# - We generate a file (a CMake fragment) in the object root which contains
|
|
# all the definitions that are required by CMake.
|
|
#
|
|
# - We generate the library table used by llvm-config.
|
|
#
|
|
# - We generate the dependencies for the CMake fragment, so that we will
|
|
# automatically reconfigure outselves.
|
|
|
|
set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
|
|
set(LLVMCONFIGLIBRARYDEPENDENCIESINC
|
|
"${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
|
|
set(LLVMBUILDCMAKEFRAG
|
|
"${LLVM_BINARY_DIR}/LLVMBuild.cmake")
|
|
|
|
if (LLVM_USE_OPROFILE)
|
|
set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
|
|
endif (LLVM_USE_OPROFILE)
|
|
|
|
message(STATUS "Constructing LLVMBuild project information")
|
|
execute_process(
|
|
COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
|
|
--native-target "${LLVM_NATIVE_ARCH}"
|
|
--enable-targets "${LLVM_TARGETS_TO_BUILD}"
|
|
--enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
|
|
--write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
|
|
--write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
|
|
OUTPUT_VARIABLE LLVMBUILDOUTPUT
|
|
ERROR_VARIABLE LLVMBUILDERRORS
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
ERROR_STRIP_TRAILING_WHITESPACE
|
|
RESULT_VARIABLE LLVMBUILDRESULT)
|
|
|
|
# On Win32, CMake doesn't properly handle piping the default output/error
|
|
# streams into the GUI console. So, we explicitly catch and report them.
|
|
if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
|
|
message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
|
|
endif()
|
|
if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
|
|
message(FATAL_ERROR
|
|
"Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
|
|
endif()
|
|
|
|
# Include the generated CMake fragment. This will define properties from the
|
|
# LLVMBuild files in a format which is easy to consume from CMake, and will add
|
|
# the dependencies so that CMake will reconfigure properly when the LLVMBuild
|
|
# files change.
|
|
include(${LLVMBUILDCMAKEFRAG})
|
|
|
|
######
|
|
|
|
# Configure all of the various header file fragments LLVM uses which depend on
|
|
# configuration variables.
|
|
set(LLVM_ENUM_TARGETS "")
|
|
set(LLVM_ENUM_ASM_PARSERS "")
|
|
foreach(t ${LLVM_TARGETS_TO_BUILD})
|
|
set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
|
|
add_definitions(-DLLVM_ENABLE_ARCH_${t})
|
|
|
|
list(FIND LLVM_ALL_TARGETS ${t} idx)
|
|
list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
|
|
if( idx LESS 0 AND idy LESS 0 )
|
|
message(FATAL_ERROR "The target `${t}' does not exist.
|
|
It should be one of\n${LLVM_ALL_TARGETS}")
|
|
else()
|
|
set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
|
|
endif()
|
|
|
|
if( EXISTS ${td}/AsmParser/CMakeLists.txt )
|
|
set(LLVM_ENUM_ASM_PARSERS
|
|
"${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
|
|
endif()
|
|
endforeach(t)
|
|
|
|
# Produce the target definition files, which provide a way for clients to easily
|
|
# include various classes of targets.
|
|
configure_file(
|
|
${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
|
|
${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
|
|
)
|
|
configure_file(
|
|
${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
|
|
${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
|
|
)
|
|
|
|
# Configure the three LLVM configuration header files.
|
|
configure_file(
|
|
${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
|
|
${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
|
|
configure_file(
|
|
${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
|
|
${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
|
|
configure_file(
|
|
${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
|
|
${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
|
|
|
|
# They are not referenced. See set_output_directory().
|
|
set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
|
|
set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
|
|
set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
|
|
|
|
set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
|
|
if (APPLE)
|
|
set(CMAKE_INSTALL_NAME_DIR "@rpath")
|
|
set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
|
|
else(UNIX)
|
|
if(NOT DEFINED CMAKE_INSTALL_RPATH)
|
|
set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
|
|
if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
|
|
set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
|
|
endif()
|
|
endif(NOT DEFINED CMAKE_INSTALL_RPATH)
|
|
endif()
|
|
|
|
if(APPLE AND DARWIN_LTO_LIBRARY)
|
|
set(CMAKE_EXE_LINKER_FLAGS
|
|
"${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
|
|
set(CMAKE_SHARED_LINKER_FLAGS
|
|
"${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
|
|
set(CMAKE_MODULE_LINKER_FLAGS
|
|
"${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
|
|
endif()
|
|
|
|
# Work around a broken bfd ld behavior. When linking a binary with a
|
|
# foo.so library, it will try to find any library that foo.so uses and
|
|
# check its symbols. This is wasteful (the check was done when foo.so
|
|
# was created) and can fail since it is not the dynamic linker and
|
|
# doesn't know how to handle search paths correctly.
|
|
if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
|
|
set(CMAKE_EXE_LINKER_FLAGS
|
|
"${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
|
|
endif()
|
|
|
|
set(CMAKE_INCLUDE_CURRENT_DIR ON)
|
|
|
|
include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
|
|
|
|
# when crosscompiling import the executable targets from a file
|
|
if(LLVM_USE_HOST_TOOLS)
|
|
include(CrossCompile)
|
|
endif(LLVM_USE_HOST_TOOLS)
|
|
if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
|
|
# Dummy use to avoid CMake Wraning: Manually-specified variables were not used
|
|
# (this is a variable that CrossCompile sets on recursive invocations)
|
|
endif()
|
|
|
|
if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
|
|
# On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
|
|
# with libxml2, iconv.h, etc., we must add /usr/local paths.
|
|
include_directories("/usr/local/include")
|
|
link_directories("/usr/local/lib")
|
|
endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
|
|
|
|
if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
|
|
SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
|
|
endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
|
|
|
|
# Make sure we don't get -rdynamic in every binary. For those that need it,
|
|
# use export_executable_symbols(target).
|
|
set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
|
|
|
|
set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
|
|
"Profiling data file to use when compiling in order to improve runtime performance.")
|
|
|
|
if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
|
|
if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
|
|
add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
|
|
else()
|
|
message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
|
|
endif()
|
|
endif()
|
|
|
|
include(AddLLVM)
|
|
|
|
if( MINGW )
|
|
# People report that -O3 is unreliable on MinGW. The traditional
|
|
# build also uses -O2 for that reason:
|
|
llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
|
|
endif()
|
|
|
|
add_subdirectory(lib/Support)
|
|
|
|
add_subdirectory(include/llvm)
|
|
|
|
add_subdirectory(lib)
|
|
|
|
add_subdirectory(keystone)
|
|
|
|
add_subdirectory(cmake/modules)
|
|
|
|
install(DIRECTORY ../include/keystone
|
|
DESTINATION include
|
|
)
|